subroutine rcont2 ( nrow, ncol, nrowt, ncolt, matrix, key, ierror )

!*****************************************************************************80
!
!! RCONT2 constructs a random 2 way contingency table with given sums.
!
!  Discussion:
!
!    It is possible to specify row and column sum vectors which
!    correspond to no table at all.  As far as I can see, this routine does
!    not detect such a case.
!
!  Modified:
!
!    04 March 2001
!
!  Reference:
!
!    WM Patefield,
!    Algorithm AS 159:
!    An Efficient Method of Generating RXC Tables with
!    Given Row and Column Totals,
!    Applied Statistics,
!    Volume 30, Number 1, 1981, pages 91-97.
!
!  Parameters:
!
!    Input, integer ( kind = 4 ) NROW, NCOL, the number of rows and columns 
!    in the table.  NROW and NCOL must each be at least 2.
!
!    Input, integer ( kind = 4 ) NROWT(NROW), NCOLT(NCOL), the row and column 
!    sums.  Each entry must be positive.
!
!    Output, integer ( kind = 4 ) MATRIX(NROW,NCOL), the matrix.
!
!    Input/output, logical KEY, a flag that indicates whether data has
!    been initialized for this problem.  Set KEY = .FALSE. before the first
!    call.
!
!    Output, integer ( kind = 4 ) IERROR, an error flag, which is returned 
!    as 0 if no error occurred.
!
  implicit none

  integer ( kind = 4 ), parameter :: maxtot = 5000

  integer ( kind = 4 ) ncol
  integer ( kind = 4 ) nrow

  real    ( kind = 8 ) dummy
  real    ( kind = 8 ), save, dimension ( maxtot+1 ) :: fact
  integer ( kind = 4 ) i
  integer ( kind = 4 ) ia
  integer ( kind = 4 ) iap
  integer ( kind = 4 ) ib
  integer ( kind = 4 ) ic
  integer ( kind = 4 ) id
  integer ( kind = 4 ) idp
  integer ( kind = 4 ) ie
  integer ( kind = 4 ) ierror
  integer ( kind = 4 ) igp
  integer ( kind = 4 ) ihp
  integer ( kind = 4 ) ii
  integer ( kind = 4 ) iip
  integer ( kind = 4 ) j
  integer ( kind = 4 ) jc
  integer ( kind = 4 ) jwork(ncol)
  logical key
  integer ( kind = 4 ) l
  logical lsm
  logical lsp
  integer ( kind = 4 ) m
  integer ( kind = 4 ) matrix(nrow,ncol)
  integer ( kind = 4 ) ncolt(ncol)
  integer ( kind = 4 ) nll
  integer ( kind = 4 ) nlm
  integer ( kind = 4 ) nlmp
  integer ( kind = 4 ) nrowt(nrow)
  integer ( kind = 4 ) nrowtl
  integer ( kind = 4 ), save :: ntotal = 0
  real    ( kind = 8 ) sumprb
  real    ( kind = 8 ) x
  real    ( kind = 8 ) y

  ierror = 0
!
!  On user's signal, set up the factorial table.
!
  if ( .not. key ) then

    key = .true.

    if ( nrow <= 1 ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'RCONT - Fatal error!'
      write ( *, '(a)' ) '  Input number of rows is less than 2.'
      ierror = 1
      return
    end if

    if ( ncol <= 1 ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'RCONT - Fatal error!'
      write ( *, '(a)' ) '  Input number of columns is less than 2.'
      ierror = 2
      return
    end if

    do i = 1, nrow
      if ( nrowt(i) <= 0 ) then
        write ( *, '(a)' ) ' '
        write ( *, '(a)' ) 'RCONT - Fatal error!'
        write ( *, '(a)' ) '  An entry in the row sum vector is not positive.'
        ierror = 3
        return
      end if
    end do

    do j = 1, ncol
      if ( ncolt(j) <= 0 ) then
        write ( *, '(a)' ) ' '
        write ( *, '(a)' ) 'RCONT - Fatal error!'
        write ( *, '(a)' ) '  An entry in the column sum vector is not positive.'
        ierror = 4
        return
      end if
    end do

    if ( sum ( ncolt(1:ncol) ) /= sum ( nrowt(1:nrow) ) ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'RCONT - Fatal error!'
      write ( *, '(a)' ) '  The row and column sum vectors do not have the same sum.'
      ierror = 6
      return
    end if

    ntotal = sum ( ncolt(1:ncol) )

    if ( ntotal > maxtot ) then
      write ( *, '(a)' ) ' '
      write ( *, '(a)' ) 'RCONT - Fatal error!'
      write ( *, '(a)' ) '  The sum of the column sum vector entries is too large.'
      ierror = 5
      return
    end if
!
!  Calculate log-factorials.
!
    x = 0.0D+00
    fact(1) = 0.0D+00
    do i = 1, ntotal
      x = x + log ( real ( i, kind = 8 ) )
      fact(i+1) = x
    end do

  end if
!
!  Construct a random matrix.
!
  do j = 1, ncol - 1
    jwork(j) = ncolt(j)
  end do

  jc = ntotal

  do l = 1, nrow-1

    nrowtl = nrowt(l)
    ia = nrowtl
    ic = jc
    jc = jc - nrowtl

    do m = 1, ncol-1

      id = jwork(m)
      ie = ic
      ic = ic - id
      ib = ie - ia
      ii = ib - id
!
!  Test for zero entries in matrix.
!
      if ( ie == 0 ) then
        matrix(l,m:ncol) = 0
        go to 190
      end if
!
!  Generate a pseudo-random number.
!
      call random_number ( harvest = dummy )
!
!  Compute the conditional expected value of MATRIX(L,M).
!
131   continue

      nlm = ia * id / real ( ie , kind = 8 ) + 0.5D+00
      iap = ia + 1
      idp = id + 1
      igp = idp - nlm
      ihp = iap - nlm
      nlmp = nlm + 1
      iip = ii + nlmp
      x = exp ( fact(iap) + fact(ib+1) + fact(ic+1) + fact(idp) - &
        fact(ie+1) - fact(nlmp) - fact(igp) - fact(ihp) - fact(iip) )

      if ( dummy <= x ) then
        go to 160
      end if

      sumprb = x
      y = x
      nll = nlm
      lsp = .false.
      lsm = .false.
!
!  Increment entry in row L, column M.
!
140   continue

      j = ( id - nlm ) * ( ia - nlm )

      if ( j == 0 ) then

        lsp = .true.

      else

        nlm = nlm + 1
        x = x * j / real ( nlm * ( ii + nlm ), kind = 8 )
        sumprb = sumprb + x

        if ( dummy <= sumprb ) then
          go to 160
        end if

      end if

      do while ( .not. lsm )
!
!  Decrement the entry in row L, column M.
!
        j = nll * ( ii + nll )

        if ( j == 0 ) then
          lsm = .true.
          exit
        end if

        nll = nll - 1
        y = y * j / real ( ( id - nll ) * ( ia - nll ), kind = 8 )
        sumprb = sumprb + y

        if ( dummy <= sumprb ) then
          go to 159
        end if

        if ( .not. lsp ) then
          go to 140
        end if

      end do

      if ( .not. lsp ) then
        go to 140
      end if

      call random_number ( harvest = dummy )
      dummy = sumprb * dummy
      go to 131

159   continue

      nlm = nll

160   continue

      matrix(l,m) = nlm
      ia = ia - nlm
      jwork(m) = jwork(m) - nlm

    end do

    matrix(l,ncol) = ia

190 continue

  end do
!
!  Compute the last row.
!
  do m = 1, ncol-1
    matrix(nrow,m) = jwork(m)
  end do

  matrix(nrow,ncol) = ib - matrix(nrow,ncol-1)

  return
end
subroutine i4vec_print ( n, a, title )

!*****************************************************************************80
!
!! I4VEC_PRINT prints an integer vector.
!
!  Modified:
!
!    28 November 2000
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, integer N, the number of components of the vector.
!
!    Input, integer A(N), the vector to be printed.
!
!    Input, character ( len = * ) TITLE, a title to be printed first.
!    TITLE may be blank.
!
  implicit none

  integer ( kind = 4 ) n

  integer ( kind = 4 ) a(n)
  integer ( kind = 4 ) big
  integer ( kind = 4 ) i
  character ( len = * ) title

  if ( title /= ' ' ) then
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) trim ( title )
  end if

  big = maxval ( abs ( a(1:n) ) )

  write ( *, '(a)' ) ' '
  if ( big < 1000 ) then
    do i = 1, n
      write ( *, '(i6,1x,i4)' ) i, a(i)
    end do
  else if ( big < 1000000 ) then
    do i = 1, n
      write ( *, '(i6,1x,i7)' ) i, a(i)
    end do
  else
    do i = 1, n
      write ( *, '(i6,i11)' ) i, a(i)
    end do
  end if

  return
end
subroutine i4mat_print ( m, n, a, title )

!*****************************************************************************80
!
!! I4MAT_PRINT prints an integer matrix.
!
!  Modified:
!
!    08 May 2000
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    Input, integer M, the number of rows in A.
!
!    Input, integer N, the number of columns in A.
!
!    Input, integer A(LDA,N), the matrix to be printed.
!
!    Input, character ( len = * ) TITLE, a title to be printed first.
!    TITLE may be blank.
!
  implicit none

  integer ( kind = 4 ) m
  integer ( kind = 4 ) n

  integer ( kind = 4 ) a(m,n)
  integer ( kind = 4 ) i
  integer ( kind = 4 ) j
  integer ( kind = 4 ) jhi
  integer ( kind = 4 ) jlo
  character ( len = * ) title

  if ( title /= ' ' ) then
    write ( *, '(a)' ) ' '
    write ( *, '(a)' ) trim ( title )
  end if

  do jlo = 1, n, 10
    jhi = min ( jlo + 9, n )
    write ( *, '(a)' ) ' '
    write ( *, '(6x,10(i7))' ) ( j, j = jlo, jhi )
    write ( *, * ) ' '
    do i = 1, m
      write ( *, '(i6,10i7)' ) i, a(i,jlo:jhi)
    end do
  end do

  return
end
subroutine timestamp ( )

!*****************************************************************************80
!
!! TIMESTAMP prints the current YMDHMS date as a time stamp.
!
!  Example:
!
!    May 31 2001   9:45:54.872 AM
!
!  Modified:
!
!    31 May 2001
!
!  Author:
!
!    John Burkardt
!
!  Parameters:
!
!    None
!
  implicit none

  character ( len = 8 ) ampm
  integer ( kind = 4 ) d
  character ( len = 8 ) date
  integer ( kind = 4 ) h
  integer ( kind = 4 ) m
  integer ( kind = 4 ) mm
  character ( len = 9 ), parameter, dimension(12) :: month = (/ &
    'January  ', 'February ', 'March    ', 'April    ', &
    'May      ', 'June     ', 'July     ', 'August   ', &
    'September', 'October  ', 'November ', 'December ' /)
  integer ( kind = 4 ) n
  integer ( kind = 4 ) s
  character ( len = 10 )  time
  integer ( kind = 4 ) values(8)
  integer ( kind = 4 ) y
  character ( len = 5 ) zone

  call date_and_time ( date, time, zone, values )

  y = values(1)
  m = values(2)
  d = values(3)
  h = values(5)
  n = values(6)
  s = values(7)
  mm = values(8)

  if ( h < 12 ) then
    ampm = 'AM'
  else if ( h == 12 ) then
    if ( n == 0 .and. s == 0 ) then
      ampm = 'Noon'
    else
      ampm = 'PM'
    end if
  else
    h = h - 12
    if ( h < 12 ) then
      ampm = 'PM'
    else if ( h == 12 ) then
      if ( n == 0 .and. s == 0 ) then
        ampm = 'Midnight'
      else
        ampm = 'AM'
      end if
    end if
  end if

  write ( *, '(a,1x,i2,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) &
    trim ( month(m) ), d, y, h, ':', n, ':', s, '.', mm, trim ( ampm )

  return
end