program main

c*********************************************************************72
c
cc rbf_interp_2d_test() tests rbf_interp_2d().
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    24 September 2012
c
c  Author:
c
c    John Burkardt
c
      implicit none

      integer g
      external phi1
      external phi2
      external phi3
      external phi4
      integer prob
      integer prob_num

      call timestamp ( )
      write ( *, '(a)' ) ''
      write ( *, '(a)' ) 'rbf_interp_2d_test():'
      write ( *, '(a)' ) '  FORTRAN77 version'
      write ( *, '(a)' ) '  Test rbf_interp_2d().'
      write ( *, '(a)' ) '  The R8LIB library is needed.'
      write ( *, '(a)' ) 
     &  '  This test also needs the TEST_INTERP_2D library.'

      call f00_num ( prob_num )
      g = 1

      do prob = 1, prob_num
        call test01 ( prob, g, phi1, 'phi1' )
        call test01 ( prob, g, phi2, 'phi2' )
        call test01 ( prob, g, phi3, 'phi3' )
        call test01 ( prob, g, phi4, 'phi4' )
      end do
c
c  Terminate.
c
      write ( *, '(a)' ) ''
      write ( *, '(a)' ) 'rbf_interp_2d_test():'
      write ( *, '(a)' ) '  Normal end of execution.'
      write ( *, '(a)' ) ''
      call timestamp ( )

      return
      end
      subroutine test01 ( prob, g, phi, phi_name )

c*********************************************************************72
c
cc RBF_INTERP_2D_TEST01 tests RBF_INTERP_2D.
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    24 September 2012
c
c  Author:
c
c    John Burkardt
c
c  Parameters:
c
c    Input, integer PROB, the index of the problem.
c
c    Input, integer G, the index of the grid.
c
c    Input, external PHI, the radial basis function.
c
c    Input, character * ( * ) PHI_NAME, the name of the radial basis function.
c
      implicit none

      integer nd_max
      parameter ( nd_max = 100 )
      integer ni_max
      parameter ( ni_max = 100 )

      double precision e
      integer g
      integer i
      double precision int_error
      integer j
      integer m
      integer nd
      integer ni
      external phi
      integer prob
      character * ( * ) phi_name
      double precision r0
      double precision r8vec_norm_affine
      double precision volume
      double precision w(nd_max)
      double precision xd(nd_max)
      double precision xmax
      double precision xmin
      double precision xyd(2,nd_max)
      double precision xyi(2,ni_max)
      double precision yd(nd_max)
      double precision ymax
      double precision ymin
      double precision zd(nd_max)
      double precision zi(ni_max)

      write ( *, '(a)' ) ''
      write ( *, '(a)' ) 'RBF_INTERP_2D_TEST01:'
      write ( *, '(a,i6)' ) 
     &  '  Interpolate data from TEST_INTERP_2D problem #', prob
      write ( *, '(a,i6)' ) '  using grid #', g
      write ( *, '(a)' ) 
     &  '  using radial basis function "' // trim ( phi_name ) // '".'

      call g00_size ( g, nd )
      write ( *, '(a,i6)' ) '  Number of data points = ', nd

      call g00_xy ( g, nd, xd, yd )

      call f00_f0 ( prob, nd, xd, yd, zd )

      if ( phi_name .eq. 'phi1' ) then
        call r8vec3_print ( nd, xd, yd, zd, '  X, Y, Z data:' )
      end if

      m = 2

      do i = 1, nd
        xyd(1,i) = xd(i)
        xyd(2,i) = yd(i)
      end do

      call r8vec_max ( nd, xd, xmax )
      call r8vec_min ( nd, xd, xmin )
      call r8vec_max ( nd, yd, ymax )
      call r8vec_min ( nd, yd, ymin )
      volume = ( xmax - xmin ) * ( ymax - ymin )

      e = 1.0D+00 / dble ( m )
      r0 = ( volume / nd ) ** e

      write ( *, '(a)' ) ' '
      write ( *, '(a,g14.6)' ) '  Setting R0 = ', r0

      call rbf_weight ( m, nd, xyd, r0, phi, zd, w )
c
c  #1:  Does interpolant match function at interpolation points?
c
      ni = nd
      do j = 1, ni
        do i = 1, 2
          xyi(i,j) = xyd(i,j)
        end do
      end do

      call rbf_interp ( m, nd, xyd, r0, phi, w, ni, xyi, zi )

      int_error = r8vec_norm_affine ( ni, zi, zd ) / dble ( ni )

      write ( *, '(a)' ) ''
      write ( *, '(a,g14.6)' ) 
     &  '  L2 interpolation error averaged per interpolant node = ', 
     &  int_error

      return
      end
      subroutine timestamp ( )

c*********************************************************************72
c
cc timestamp() prints the YMDHMS date as a timestamp.
c
c  Licensing:
c
c    This code is distributed under the MIT license.
c
c  Modified:
c
c    12 June 2014
c
c  Author:
c
c    John Burkardt
c
      implicit none

      character * ( 8 ) ampm
      integer d
      character * ( 8 ) date
      integer h
      integer m
      integer mm
      character * ( 9 ) month(12)
      integer n
      integer s
      character * ( 10 ) time
      integer y

      save month

      data month /
     &  'January  ', 'February ', 'March    ', 'April    ', 
     &  'May      ', 'June     ', 'July     ', 'August   ', 
     &  'September', 'October  ', 'November ', 'December ' /

      call date_and_time ( date, time )

      read ( date, '(i4,i2,i2)' ) y, m, d
      read ( time, '(i2,i2,i2,1x,i3)' ) h, n, s, mm

      if ( h .lt. 12 ) then
        ampm = 'AM'
      else if ( h .eq. 12 ) then
        if ( n .eq. 0 .and. s .eq. 0 ) then
          ampm = 'Noon'
        else
          ampm = 'PM'
        end if
      else
        h = h - 12
        if ( h .lt. 12 ) then
          ampm = 'PM'
        else if ( h .eq. 12 ) then
          if ( n .eq. 0 .and. s .eq. 0 ) then
            ampm = 'Midnight'
          else
            ampm = 'AM'
          end if
        end if
      end if

      write ( *, 
     &  '(i2,1x,a,1x,i4,2x,i2,a1,i2.2,a1,i2.2,a1,i3.3,1x,a)' ) 
     &  d, trim ( month(m) ), y, h, ':', n, ':', s, '.', mm, 
     &  trim ( ampm )

      return
      end